PUSH:   MACRO (ra)
        sub   r30,r30,4
        st    ra,r30,0
  ENDMACRO
POP:    MACRO (ra)
        ld    ra,r30,0
        add   r30,r30,4
  ENDMACRO
;Aprovechando que el exponente está representado en exceso y ocupa los 8 bits
;detrás del signo, la comparación puede realizarse directamente sobre los
;operandos sin separar exponentes y mantisas. El algoritmo quedaría:
;Si S1<>S2, entonces el mayor es el negativo.
;Si S1=S2=0, se comparan Op1 y Op2 como números en binario sin signo:
	;Si Op1>Op2, devolver r29=-1
	;Si Op1<Op2, devolver r29=+1
	;Si Op1=Op2, devolver r29= 0.
;Si S1=S2=1, se comparan Op1 y Op2 como números en binario sin signo:
        ;Si Op1>Op2, devolver r29=+1
        ;Si Op1<Op2, devolver r29=-1
        ;Si Op1=Op2, devolver r29= 0.
;La rutina COMPARAR quedaría:
COMPARAR:   PUSH  (r1)             ;Se salva la direccion de retorno.
            ld    r10,r30,4        ;Se carga Op1.
            ld    r20,r30,8        ;Se carga Op2.
            xor   r7,r10,r20
            bb1   31,r7,SIGNOS_DIF
            bb1   31,r10,NEGATIVOS ;Si los signos son iguales se
            cmp   r7,r10,r20       ;comparan los operandos.
            bb1   8,r7,MAYOR
            bb1   10,r7,MENOR
IGUAL:      add   r29,r0,r0
            br    RETORNA
NEGATIVOS:  cmp   r7,r10,r20
            bb1   8,r7,MENOR
            bb1   10,r7,MAYOR
            br    IGUAL
SIGNOS_DIF: bb1   31,r10,MENOR
MAYOR:      add   r29,r0,-1
            br    RETORNA
MENOR:      add   r29,r0,1
RETORNA:    POP   (r1)
            jmp   (r1)

;PROGRAMA LLAMANTE

llamante:   addu  r30,r0,50000     ;Se inicializa el puntero de pila.
            or    r2,r0,low(Op2)
            or.u  r2,r2,high(Op2)
            ld    r2,r2,r0
            PUSH  (r2)
            or    r2,r0,low(Op1)
            or.u  r2,r2,high(Op1) 
            ld    r2,r2,r0
            PUSH  (r2)
            bsr   COMPARAR
            stop
Op1:    data    0xC0C00000
Op2:    data    0xC0CC0000