PUSH:   MACRO(ra)
        subu r30,r30,4
        st   ra,r30,0
ENDMACRO
POP:    MACRO(ra)
        ld   ra,r30,0
        addu r30,r30,4
ENDMACRO
LEA:   MACRO (ra, eti)     ;Carga el registro ra con el
       or ra, r0, low(eti) ;valor de la etiqueta eti.
       or.u ra,ra,high(eti)
ENDMACRO

CHAR_CMP:
     PUSH (r1)
     ld   r1,r30,4       ;r1 contiene el carácter c1.
     ld   r2,r30,8       ;r2 contiene el carácter c2.
     clr  r1,r1,1<5>     ;Se pasa c1 a mayúscula.
     clr  r2,r2,1<5>     ;Se pasa c2 a mayúscula.
     cmp  r4,r1,r2       ;Se comparan los dos caracteres.
     bb1  hi,r4,MAYOR_C1
     bb1  lo,r4,MENOR_C1
     add  r29,r0,r0      ;Si son iguales r29=0.
     br   FIN_CH
MAYOR_C1: add r29,r0,1   ;Si c1>c2 se carga r29=1.
     br   FIN_CH
MENOR_C1: add r29,r0,-1  ;Si c1<c2 se carga r29=-1.
FIN_CH:   POP(r1)
     jmp (r1)

NAME_CMP:
     PUSH (r1)
     ld   r10,r30,4      ;r10 contiene dir_nombre1.
     ld   r20,r30,8      ;r20 contiene dir_nombre2.
BUCLE_C: ld.bu r11,r10,0 ;r11 contiene c1i.
         ld.bu r21,r20,0 ;r21 contiene c2j.
     cmp  r4,r11,0       ;Se compara c1i con 0 (NUL).
     bb0  eq,r4,NO_CERO1
     cmp  r4,r21,0       ;Si c1i=0 se compara c2j con 0 (NUL)
     bb0  eq,r4,NO_CERO2
     add  r29,r0,0       ;y si c2j también es 0 se
     br   FIN_NAME       ;devuelve r29=0,
NO_CERO2: add  r29,r0,-1 ;y si c2j no es 0 se
     br   FIN_NAME       ;devuelve r29=-1.
NO_CERO1: cmp  r4,r21,0  ;Si c1i no es 0 se compara c2j con 0
     bb0  eq,r4,BLANCO   ;y si es 0 se devuelve r29=1.
     add  r29,r0,1
     br   FIN_NAME
BLANCO:
     cmp  r4,r11,0x20    ;Si c1i es un blanco se saltan todos
     bb0  eq,r4,SEGUIR1  ;los blancos hasta acceder a un
     add  r10,r10,1      ;carácter alfabético.
     ld.bu  r11,r10,0
     br   BLANCO
SEGUIR1:
     cmp  r4,r21,0x20    ;Si c2j es un blanco se saltan todos
     bb0  eq,r4,SEGUIR2  ;los blancos hasta acceder a un
     add  r20,r20,1      ;carácter alfabético.
     ld.bu  r21,r20,0
     br   SEGUIR1
SEGUIR2:
     PUSH (r21)          ;Se compara c1i con c2j
     PUSH (r11)
     bsr  CHAR_CMP
     addu r30,r30,8      ;y se desapila,
     bb1  0,r29,FIN_NAME ;si no son iguales se ha terminado,
     add  r10,r10,1      ;si son iguales se incrementan los
     add  r20,r20,1      ;punteros de nombre1 y de nombre2.
     br BUCLE_C
FIN_NAME: POP(r1)
          jmp (r1)

ORDENAR: PUSH (r1)
INICIO:  ld   r5,r30,4       ;r5 contiene dir_lista.
         add  r8,r0,r0       ;Se inicializa Cambio=false.
         ld   r6,r5,0        ;r6 contiene dir_N.
         cmp  r4,r6,0        ;Se comprueba si fin de lista.
         bb1  eq,r4,FIN_ORD
BUCLE_O: ld   r7,r5,4        ;r7 contiene dir_Ns.
         cmp  r4,r7,0        ;Se comprueba si fin de lista.
         bb1  eq,r4,FIN_ORD
         PUSH (r7)
         PUSH (r6)
         bsr  NAME_CMP       ;Se compara N y Ns.
         addu r30,r30,8      ;Se desapila.
         bb0  0,r29,SEGUIR   ;Si N=Ns se pasa al siguiente.
         bb1  31,r29,SEGUIR  ;Si N<Ns se pasa al siguiente.
         st   r7,r5,0        ;Si N>Ns se intercambian los
         st   r6,r5,4        ;punteros.
         add  r8,r0,1        ;Se hace Cambio=true.
SEGUIR:  add  r5,r5,4        ;Se incrementa el puntero a la
         ld   r6,r5,0        ;lista y Ns es el nuevo valor de N.
         br   BUCLE_O
FIN_ORD: bb0  0,r8,FINAL     ;Si Cambio=false la lista está
         br   INICIO         ;ordenada, si no se vuelve a
FINAL:  POP(r1)              ;empezar
        jmp(r1)

PPAL:   addu  r30,r0,60004
        LEA   (r2,LISTA)
        PUSH  (r2)
        bsr   ORDENAR
        stop


LISTA:  data  10000, 10100, 10200, 10300, 0
        org   10000
        data  "LUNA LUNA JOSE LUIS\0"
        org   10100
        data  "Luna Luna Jose\0"
        org   10200
        data  "GARCIA   PEREZ JESUS\0"
        org   10300 
        data  "GARCIA BLANCO JESUS\0"